La clase ArrayCollection incluye una propiedad heredada de ListCollectionView llamada filterFunction con la cual podemos mandar llamar una función que nos devolverá un valor Boolean con el cual evaluaremos si al final el ArrayCollection muestra o no algún elemento.

Antes de mostrar el ejemplo de uso, veamos como tenemos que construir la función que será el valor de la propiedad filterFunction:
ff(item:Object):Boolean

El nombre de la función lo escoge el desarrollador, sin embargo, el parámetro de entrada y el tipo de dato de regreso si se tienen que especificar según lo indica la documentación. El parámetro de entrada tiene que ser de tipo Object, pues es cada elemento del proveedor de datos que estará mandando a la función para evaluar y el tipo de dato de regreso es de tipo Boolean, pues cuando sea true se agregará al proveedor y cuando sea false se ignorará.

A continuación un ejemplo de como un proveedor de datos tipo ArrayCollection funciona sobre ComboBox, List y DataGrid’s:

para ver el código y descargar el proyecto, click derecho sobre el swf y luego click en View Source.

Nota: el ejemplo fue hecho en Flash Builder 4 con el Flex SDK 4.0, si se quisiera probar en Flex Builder 3 únicamente se cambian los componentes por los mx y el código en AS3 quedaría igual.

Los que hemos trabajado en Flex con Listas o ComboBox hemos visto que algunas veces las etiquetas de cada item rebasan el tamaño del control provocando que esta no se vea por completo, para el control List podemos resolver eso fácilmente poniendo en true la propiedad showDataTips, sin embargo para el ComboBox no hay algo tan directo como esto, la solución es crear un dropdownFactory, con esto creamos una nueva instancia del control List (pues el control que aparece en el drop down del ComboBox es un List) y podrémos modificar las propiedades que necesitemos, para este caso, que muestre dataTips y especificar quien será el dataTip o bien, crear una función para que sea la que despliegue la información.
El código en AS3 quedaría así:

private var ddf:ClassFactory
private var dp_ac:ArrayCollection = new ArrayCollection([
   {etiqueta: "Texto un poco laaaaaargo"},
   {etiqueta: "Texto un poco laaaaaargo"},
   {etiqueta: "Texto un poco laaaaaargo"},
   {etiqueta: "Texto un poco laaaaaargo"},
   {etiqueta: "Texto un poco laaaaaargo"},
   {etiqueta: "Texto un poco laaaaaargo"},
   {etiqueta: "Texto un poco laaaaaargo"}
]);

//donde init se dispara en el creationComplete del .mxml
private function init():void
{
   ddf = new ClassFactory(List);
   var propiedades:Object = {
      showDataTips: true,
      dataTipField: "etiqueta"
   }
   ddf.properties = propiedades;
   var cb:ComboBox = new ComboBox();
   cb.dropdownFactory = ddf;
   cb.dataProvider = dp_ac;
   cb.width = 75;
   cb.labelField = "etiqueta";
   this.addChild(cb);
}

en caso de que el ComboBox se haga desde el MXML el código sería así (eliminando desde var cb:ComboBox = new ComboBox(); hasta this.addChild(cb); del código anterior):

<mx:ComboBox id="cb" dataProvider="{dp_ac}" dropdownFactory="{ddf}" width="75" labelField="etiqueta"/>

y ya en la ejecución se vería como la siguiente imagen:

Como ya tenía harto, harto tiempo de no publicar un tip de Flex en el blog, hoy es momento de regresar a eso.

Bien, en este tip mostraré como podemos hacer funcionar el trim() de AS3 como el trim() de PHP, la diferencia entre estos dos métodos, es que con el de PHP no solo podemos eliminar espacios en blanco la inicio y final de la cadena, sino que podemos definir caracteres que también sean eliminados.

La implementación de este trim() para AS3 fué tomada en base a la clase StringUtils del blog gskinner.

el método original es el siguiente:

public static function trim(p_string:String):String {
   if (p_string == null) { return ''; }
   return p_string.replace(/^\s+|\s+$/g, '');
}

aquí la magia esta en la línea del return, donde le indica al método que regrese lo que reemplace de la cadena según la expresión regular que esta definiendo, lo que hace que elimine los espacios es el caracter \s por lo que este caracter es el que tenemos que sustituir en nuestro nuevo método, además de que tenemos que agregar otro parámetro para definir cual será el caracter a reemplazar, ya modificado el método nos quedaría algo así:

public static function trimChar(p_string:String, p_char:String = ' '):String
{
   if (!p_string)
   {
      return '';
   }
   var regexp:RegExp = new RegExp("^" + p_char + "+|" + p_char + "+$", "g");
   return p_string.replace(regexp, '');
}

suponiendo que el método se agregue a una clase llamada StringUtils, la utilización de esta clase sería:

var foo:String = "   lDaniel Daniel   ";
trace(StringUtils.trimChar(foo)); //lDaniel Daniel
trace(StringUtils.trimChar(StringUtils.trimChar(foo), "l")); //Daniel Danie

este método es para eliminar de ambos lados de la cadena, si solo se quisiera eliminar de un solo lado, se reemplaza el valor de la variable regexp según sea necesario o bien, se crean dos métodos nuevos cada uno con cada definición de la variable:

//para hacer un trim de lado izquierdo
var regexp:RegExp = new RegExp("^" + p_char + "+", "g");
//para hacer un trim de lado derecho
var regexp:RegExp = new RegExp(p_char + "+$", "g");

Espero que les sirva, Saludos!